Programmier- und Bedienungshandbuch – Komplizierte Fälle

˙

A.4.1.  Komplizierte Fälle

Kompliziertere Auslöser als Computer-Tasten oder MIDI-Nachrichten sind Harmonien und Harmonieformen. (Eigentlich handelt es sich hierbei um “Tastenmuster„, denn eine Harmonieanalyse im Sinne der Musikwissenschaft ist mit MUTABOR noch nicht möglich.) Hier wird eine Harmonie als Menge von gedrückten Tasten in der Projektionstonleiter verstanden. Beim Erkennen der angegebenen Harmonie gilt der Auslöser als erfüllt. Beispiel:

    HARMONIE  
          c_dur   = {0, 4, 7}  
          cis_dur = {1, 5, 8}  
          d_dur   = {2, 6, 9}  
          dis_dur = {3, 7, 10}  
          e_dur   = {4, 8, 11}  
 
    LOGIK mutiere_dur Taste M = [  
                 c_dur   -> u1  
                 cis_dur -> u2  
                 d_dur   -> u3  
                 dis_dur -> u4  
                 e_dur   -> u5  
               ansonsten -> u99  
             ]

Sobald die Logik mutiere_dur aktiviert ist, wird bei jeder der fünf angegebenen Harmonien eine Umstimmung durchgeführt. Falls in einem Moment mal keine der Harmonien zutrifft (sondern ein anderes Tastenmuster gedrückt ist) wird die Umstimmung u99 durchgeführt.

Man kann auch eine Harmonie-Form Analyse durchführen, bei der es nicht auf die Verschiebung der Harmonie bezüglich des Grundtons ankommt:

    HARMONIE  
          dur   = {0, 4, 7}  
 
    LOGIK mutiere_dur_2 Taste M = [  
                 FORM dur   -> umst (ABSTAND)  
                 ansonsten  -> u99  
             ]

Hier wird jede Dur-Harmonieform erkannt, und zwar nicht nur die fünf Harmonien aus dem vorigen Beispiel, sondern alle zwölf Harmonieformen – vorausgesetzt, die Breite des Tonsystems ist zwölf. In dem Parameter ABSTAND wird als Nummer mitgegeben, um wieviele Tastenschritte die erkannte Harmonie vom Prototyp der Harmonieform entfernt ist, ABSTAND liefert also die Stufe, auf der die erkannte Harmonie bezüglich dem aktuellen Zentrum (=Verankerungstaste) steht. Man könnte dies für eine Auswählende Umstimmung verwenden und die Umstimmung umst definieren als:

    UMSTIMMUNG  
        umst (x) = x {  
                       0 -> u1  "Fall c_dur"  
                       1 -> u2  "Fall cis_dur"  
                       2 -> u3  "Fall d_dur"  
                       3 -> u4  "Fall dis_dur"  
                       4 -> u5  "Fall e_dur"  
                 }

Möchte man zusätzlich erreichen, dass nicht jeder Dur-Dreiklang erkannt wird, so kann man noch folgende Einschränkungen machen:

    HARMONIE  
          dur   = {0, 4, 7}  
 
    LOGIK mutiere_dur_3 Taste M = [  
                 FORM 4 ~ dur  -> umst (ABSTAND)  
             ]

Jetzt wird die Harmonie-Form Analyse genauso durchgeführt, aber der tiefste Ton muss vom Tonigkeitstyp 4 sein. Ebenso kann einschränkend gesagt werden, dass der höchste Ton von einer bestimmten Art sein soll:

    HARMONIE  
          dur   = {0, 4, 7}  
 
    LOGIK mutiere_dur_3 Taste M = [  
                 FORM dur ~ 7  -> umst (ABSTAND)  
             ]

Jetzt reagiert der Auslöser dur ~ 7 nur dann, wenn der höchste Ton ein g ist. (Bei zwölfstufiger Fundamentaltonleiter). Es sind auch beide Einschränkungen gleichzeitig zugelassen. Durch diese einschränkende Analyse können verschiedene Lagen und Umkehrungen derselben Harmonieform unterschiedliche Umstimmungen auslösen.

˙

Deutsch English
©2006
Letzte Veröffentlichung auf dem Server:
Mittwoch, 29. März 2006, 13.51 Uhr Mitteleuropäischer Sommerzeit